九九博客
域名介绍 网络资讯 客户服务交流 - 欢迎浏览九九博客 !

ASP使用Jmail发送电子邮件的范例

时间:2012/4/1 浏览:39 标签:ASP Jmail 发送邮件

<1>最常使用的代码范例:
以下是ASP使用Jmail发送电子邮件最为常用的代码:
注意要正确设置相关的参数才能够发送邮件,并且是你所在的网站服务器支持Jmail组件.
Dim Email
Email="www@xxx.la "'这里是定义一个收件人的邮件地址
'如果是用于表单则应该是:Email="trim(request("email"))"
Set jmail = Server.CreateObject("JMAIL.SMTPMail") '创建一个JMAIL对象
jmail.silent = true 'JMAIL不会抛出例外错误,返回的值为FALSE跟TRUE
jmail.logging = true '启用使用日志
jmail.Charset = "GB2312" '邮件文字的代码为简体中文
jmail.ContentType = "text/html" '邮件的格式为HTML的
jmail.ServerAddress = "mail.xxx.la" '发送邮件的服务器 这里填写你的邮件发送的服务器地址
jmail.AddRecipient Email '邮件的收件人
jmail.SenderName = "info" '邮件发送者的姓名
jmail.Sender = "info@xxx.la" '邮件发送者的邮件地址
jmail.Priority = 1 '邮件的紧急程序,1 为最快,5 为最慢, 3 为默认值
jmail.Subject = "Puer.la欢迎您!" '邮件的标题
jmail.Body = "MailBox:mail.puer.la" '邮件的内容
jmail.Execute() '执行邮件发送
jmail.Close '关闭邮件对象
保存并运行上面的代码收到邮件(注意加上<%%>)!
<2>使用下面的代码需要身份认证:
Dim Email
Email="www@puer.la" '这里是定义一个收件人的邮件地址
'如果是用于表单则应该是:Email="trim(request("email"))"
Set jmail = Server.CreateObject("JMAIL.Message") '建立发送邮件的对象
jmail.silent = true '屏蔽例外错误,返回FALSE跟TRUE两值j
Jmail.logging = true '启用邮件日志
jmail.Charset = "GB2312" '邮件的文字编码为国标
jmail.ContentType = "text/html" '邮件的格式为HTML格式
jmail.AddRecipient Email '邮件收件人的地址
jmail.From = "info@puer.la" '发件人的E-MAIL地址
jmail.MailServerUserName = "info@puer.la" '登录邮件服务器所需的用户
名
jmail.MailServerPassword = "明文密码123" '登录邮件服务器所需的密码
jmail.Subject = "puer.la管理员至您的私人邮件,请您确认!" '邮件的标题
jmail.Body = "Hi,这是爱玛的系统邮件!" '邮件的内容
jmail.Send("mail.xxx.la") '执行邮件发送(通过邮件服务器地址)
jmail.Close() '关闭对象 
保存并运行上面的代码收到邮件(注意加上<%%>)!
<3>以下是本站所使用的代码:
优点在于调用方便,服务器的信息可以一次设置.转载请注明来源于[爱玛网络]
<!--#include file="ip.asp"-->
<script language=VBScript runat=server>
function SendMail(SenderName,mailto,subjects,msg)'这个是一个函数,在程序中可以直接调用。
on error resume next
Dim amail
amail="www@cnnic.net.cn" '举例,设定一个密秘收件人(CNNIC)
Set jmail = Server.CreateObject("JMAIL.Message") '建立发送邮件的对象
jmail.silent = true '屏蔽例外错误,返回FALSE跟TRUE两值j
Jmail.logging = true '启用邮件日志
jmail.Charset = "GB2312" '邮件的文字编码为国标
jmail.ContentType = "text/html" '邮件的格式为HTML格式
jmail.AddRecipient mailto '邮件收件人的地址
jmail.AddRecipientBCC amail'隐藏的副本抄送,只有发件人和BCC收件人知道。
jmail.FromName =SenderName '发件人名称
jmail.From = "info@21cn.com" '发件人的E-MAIL地址
jmail.MailServerUserName = "info@21cn.com" '登录邮件服务器所需的用户名
jmail.MailServerPassword = "密码123654" '登录邮件服务器所需的密码
jmail.Subject =subjects '邮件的标题
jmail.Body =msg '邮件的内容
jmail.Send("smtp.21cn.com") '执行邮件发送(通过邮件服务器地址)
jmail.Close() '关闭对象
end function
</script>
以上代码可以保存为任意你的名字,如mail.asp
以下自行根据你的需要设置
<!--#include file="mail.asp"-->
<%
'JMAIL调用说明:
Dim Email,user
Email=trim(request.Form("email"))
user=trim(request.Form("user"))
strHTML = "<table width=""80%"" border=""0"" height=150>"&chr(13) &chr(10) '这里需要加上两个
strHTML = strHTML & " <tr>"&chr(13)&chr(10) 'chr(13)硬回车chr(10)软回车
strHTML = strHTML & "<td align=""left"" valign=""middle"" height=150>亲爱的用户朋友 "&user&":<br>   "&chr(13) &chr(10)
strHTML = strHTML & "<br>以下是你在爱玛网站的注册信息(请保存好本封邮件):<br><hr size=""1"" color=""#000000"" noshade>登录密码:<font color=""red"">"&trim(request.form("Password"))&"</font><br>注册信箱:<font color=""red"">"&Email&"</font>;<br>"&chr(13) &chr(10)
strHTML = strHTML & "密码问题:<font color=""red"">"&trim(request.form("wt"))&"</font>;<br>问题答案:<font color=""red"">"&trim(request.form("wtda"))&"</font>;<br><hr size=""1"" color=""#000000"" noshade><br>"&chr(13) &chr(10)
strHTML = strHTML & "如果您还需要其他帮助,敬请随时和我们联系。谢谢您的支持!<br>注册时间:"&now()&"<br>注册IP:"&getIP()&"<hr size=""1"" color=""#000000"" noshade><br>" &chr(13) &chr(10)
strHTML = strHTML & "地址:四川省成都市芳华街XX号<br>"&chr(13) &chr(10)
strHTML = strHTML & "邮编:630000 <br>"&chr(13) &chr(10)
strHTML = strHTML & "QQ:372512020 <br>"&chr(13) &chr(10)
strHTML = strHTML & "Web:<a href=http://www.amchina.net/ target='_blank'>http://www.amchina.net</a><br>"&chr(13) &chr(10)
strHTML = strHTML & "Email:ee@xxx.com <br>"&chr(13) &chr(10)
strHTML = strHTML & "<br>祝 <br>"&chr(13) &chr(10)
strHTML = strHTML & "商祺!<br>"&chr(13) &chr(10)
strHTML = strHTML & "<br>"&chr(13) &chr(10)
strHTML = strHTML & "<br><div align=right>爱玛网发送于"&now()&"<br>此信由爱玛网络自动发送,无需回复!</div><br>"&chr(13) &chr(10)
strHTML = strHTML & "</td></tr></table>"
SenderName="爱玛网客服部"
mailto=""&Email&"" '收信人email
subjects="爱玛欢迎您!这是系统自动发送给您的注册确认邮件!"
msg="<HTML><title>AmChina.net</title><meta http-equiv=""Content-Type"" content=""text/html; charset=gb2312""><link href=""http://www.amchina.net/jmailcss.css"" rel=""stylesheet"" type=""text/css""><BODY><CENTER>" & strHTML & "</CENTER></BODY></HTML>"
call SendMail(SenderName,mailto,subjects,msg)
%>
下面一并给出IP.asp的源程序:
Private Function getIP()
Dim strIPAddr
If Request.ServerVariables("HTTP_X_FORWARDED_FOR") = "" OR InStr(Request.ServerVariables("HTTP_X_FORWARDED_FOR"), "unknown") > 0 Then
strIPAddr = Request.ServerVariables("REMOTE_ADDR")
ElseIf InStr(Request.ServerVariables("HTTP_X_FORWARDED_FOR"), ",") > 0 Then
strIPAddr = Mid(Request.ServerVariables("HTTP_X_FORWARDED_FOR"), 1, InStr(Request.ServerVariables("HTTP_X_FORWARDED_FOR"), ",")-1)
ElseIf InStr(Request.ServerVariables("HTTP_X_FORWARDED_FOR"), ";") > 0 Then
strIPAddr = Mid(Request.ServerVariables("HTTP_X_FORWARDED_FOR"), 1, InStr(Request.ServerVariables("HTTP_X_FORWARDED_FOR"), ";")-1)
Else
strIPAddr = Request.ServerVariables("HTTP_X_FORWARDED_FOR")
End If
getIP = Trim(Mid(strIPAddr, 1, 30))
End Function
 
『欢迎投稿』
如果有自己原创、有推荐价值或是与网络相关转载的文章请联系我们!将有机会获得免费个性域名;>>详细
Copyright ©2008-2017 九九博客 - www.99.my™ 返回顶部 All Rights Reserved